home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD008b.dsk / VOCAB.bas < prev    next >
BASIC Source File  |  2003-06-12  |  5KB  |  155 lines
  1. 100  REM :VOCABULARY QUIZ
  2. 110  REM  :COPYRIGHT BY RUGG AND  FELDMAN
  3. 300  GOSUB 1000
  4. 400  GOSUB 2000
  5. 500  GOSUB 3000
  6. 600  GOSUB 4000
  7. 700  GOSUB 5000
  8. 800  GOSUB 6000
  9. 900  IF E = 0  THEN 500
  10. 910  GOTO 300
  11. 1000  IF E < >0  THEN 1060
  12. 1010  HOME 
  13. 1020  PRINT "*****VOCABULARY QUIZ*****"
  14. 1030  PRINT 
  15. 1040  PRINT "THIS PROGRAM WILL TEST YOUR KNOWLEDGE"
  16. 1050  PRINT "OF SOME USEFUL VOCABULARY WORDS"
  17. 1060  PRINT 
  18. 1110  INPUT "HOW MANY QUESTIONS SHALL WE DO? ";L
  19. 1120  IF L >4  THEN 1140
  20. 1130  PRINT "THAT'S NOT ENOUGH. LET'S DO 5.":L = 5
  21. 1140  IF E < >0  THEN 1200
  22. 1150  PRINT 
  23. 1200  RETURN 
  24. 2000  IF E < >0  THEN 2200
  25. 2010 C = 5
  26. 2020 D = 250
  27. 2030  DIM D$(D),E$(D)
  28. 2040  DIM P(C)
  29. 2050 J = 1
  30. 2060  READ D$(J)
  31. 2070  IF D$(J) = "XXX"  THEN 2140
  32. 2090  READ E$(J)
  33. 2100 J = J +1
  34. 2110  IF J < = D  THEN 2060
  35. 2120  PRINT "TOO MANY DATA STATEMENTS."
  36. 2130  PRINT "ONLY FIRST";D;"ARE USED."
  37. 2140 D = J -1
  38. 2200 Q = 1
  39. 2210 E = 0
  40. 2220 Q1 = 0
  41. 2300  RETURN 
  42. 3000  FOR J = 1 TO C
  43. 3010 P(J) = 0
  44. 3020  NEXT J
  45. 3030  FOR J = 1 TO C
  46. 3040 P =  RND(5)
  47. 3041 P = P *D +1
  48. 3042 P =  INT(P)
  49. 3045  IF (P = P1)  OR (P = P2)  OR (P = P3)  THEN 3040
  50. 3050  FOR K = 1 TO J
  51. 3060  IF P(K) = P  THEN 3040
  52. 3070  NEXT K
  53. 3080 P(J) = P
  54. 3090  NEXT J
  55. 3110 A =  RND(3)
  56. 3111 A = A *C +1
  57. 3112 A =  INT(A)
  58. 3200  RETURN 
  59. 4000  PRINT 
  60. 4010 M =  RND(7)
  61. 4011 M = M *2 +1
  62. 4012 M =  INT(M)
  63. 4020  IF M = 2  THEN 4100
  64. 4030  PRINT Q;"--WHAT WORD MEANS ";E$(P(A));"?"
  65. 4040  FOR J = 1 TO C
  66. 4050  PRINT  TAB( 5);J;"-- ";D$(P(J))
  67. 4060  NEXT 
  68. 4070  GOTO 4210
  69. 4100  PRINT Q;"-- WHAT DOES ";D$(P(A));" MEAN?"
  70. 4110  FOR J = 1 TO C
  71. 4120  PRINT  TAB( 5);J;"-- "E$(P(J))
  72. 4130  NEXT 
  73. 4210  RETURN 
  74. 5000  INPUT R
  75. 5010  IF R > = 1  AND R < = C  THEN 5050
  76. 5020  PRINT "I NEED A NUMBER FROM 1 TO ";C
  77. 5030  GOTO 5000
  78. 5050  IF R = (A)  THEN 5100
  79. 5060  PRINT "NO, THE ANSWER IS NUMBER ";A
  80. 5070  GOTO 5210
  81. 5100  PRINT "RIGHT"
  82. 5110 Q1 = Q1 +1
  83. 5210  IF Q1 = 1  THEN 5300
  84. 5220  PRINT "YOU HAVE ";Q1;" RIGHT OUT OF ";Q;" QUESTIONS."
  85. 5300 P3 = P2
  86. 5310 P2 = P1
  87. 5320 P1 = P(A)
  88. 5330  RETURN 
  89. 6000 Q = Q +1
  90. 6010  IF Q < = L  THEN  RETURN 
  91. 6020 E = 1
  92. 6030 Q = Q1 *100/(Q -1)
  93. 6040  IF Q >0  THEN 6070
  94. 6050  PRINT "WELL, THAT'S A ''PERFECT '' SCORE...."
  95. 6060  GOTO 6200
  96. 6070  PRINT "THAT'S ";Q;"PERCENT."
  97. 6080  IF Q >25  THEN 6110
  98. 6090  PRINT "CONGRATULATIONS ON AVOIDING A SHUTOUT."
  99. 6100  GOTO 6200
  100. 6110  IF Q >50  THEN 6140
  101. 6120  PRINT "YOU CAN USE SOME MORE PRACTICE."
  102. 6130  GOTO 6200
  103. 6140  IF Q >75  THEN 6170
  104. 6150  PRINT "NOT BAD, BUT ROOM FOR IMPROVEMENT."
  105. 6160  GOTO 6200
  106. 6170  PRINT "VERY GOOD!!"
  107. 6180  IF Q >95  THEN  PRINT "YOU'RE ALMOST AS SMART AS I AM!!!"
  108. 6200  PRINT 
  109. 6210  INPUT "WANT TO TRY AGAIN? ";R$
  110. 6220  IF  LEFT$(R$,1) < >"N"  THEN 6240
  111. 6230  PRINT : PRINT "CHECK YOU LATER.": PRINT : END 
  112. 6240  IF  LEFT$(R$,1) < >"Y"  THEN 6210
  113. 6250  RETURN 
  114. 7000  REM :D MUST BE AT LEAST ONE GREATER THAN THE NUMBER OF DIFFERENT WORDS.
  115. 7010  DATA  ANOMYMOUS,"OF UNKNOWN OR HIDDEN ORIGIN"
  116. 7020  DATA OMINOUS,"THREATENING OR MENACING"
  117. 7030  DATA AFFLUENT,"WEALTHY"
  118. 7040  DATA APATHETIC,"INDIFFERENT OR UNINTERESTED"
  119. 7050  DATA LACONIC,"TERSE"
  120. 7060  DATA INTREPID,"FEARLESS OR COURAGEOUS"
  121. 7070  DATA GREGARIOUS,"SOCIAL OR COMPANY-LOVING"
  122. 7080  DATA  ENERVATED,"WEAK OR EXHAUSTED"
  123. 7090  DATA  VENERABLE,"WORTHY OF RESPECT OR REVERENCE"
  124. 7100  DATA DISPARATE,"DIFFERENT AND DISTINCT"
  125. 7110  DATA VIVACIOUS,"LIVELY OR SPIRITED"
  126. 7120  DATA ASTUTE,"KEEN IN JUDGMENT"
  127. 7130  DATA URSINE,"BEARLIKE"
  128. 7140  DATA PARSIMONIOUS,"STINGY OR FRUGAL"
  129. 7150  DATA OMNISCIENT,"ALL-KNOWING"
  130. 7160  DATA SESQUIPEDALIAN,"LONG WORDS"
  131. 7170  DATA BROBDINGNAGIAN,"LARGER THAN GIGANTIC"
  132. 7180  DATA SIALOGOGUE,"MAKE MOUTH WATER"
  133. 7190  DATA NEPHALISM,"TOTAL ABSTINENCE FROM ALCOHOLIC DRINKS"
  134. 7200  DATA  THEOMACHY,"BATTLES AMONG THE GODS"
  135. 7210  DATA  INGRAVESCENCE,"WORSENING OR INCREASE IN SEVERITY"
  136. 7220  DATA  HYSTERESIS,"LAG BETWEEN CAUSE AND EFFECT"
  137. 7230  DATA  NIDIFICATING,"NEST BUILDING"
  138. 7240  DATA  TRIUMVIRATE,"GOVERNANCE BY THREE PERSONS"
  139. 7250  DATA  CINERARIUM,"LOCATION OF CREMATED REMAINS"
  140. 7260  DATA  TRANSPONTINE,"OTHER SIDE OF THE BRIDGE"
  141. 7270  DATA  HAPLOGRAPHY,"INADVERTENT OMISSION OF A LINE WORD OR PART OF A WORD DUE TO ITS SIMILARITY TO ANOTHER"
  142. 7280  DATA  TERATOLOGY,"MONSTER STORY CREATION"
  143. 7290  DATA  BREVILOQUENCE,"BRIEF BUT EFFECTIVE SPEECH"
  144. 7300  DATA PANDICULATE,"YAWN"
  145. 7310  DATA CICERON,"TOUR GUIDE"
  146. 7320  DATA SEGUED,"FLOW FROM ONE MUSICAL NOTE TO ANOTHER W/O PAUSE"
  147. 7330  DATA  INVIDIOUS,"CAUSE DISCONTENT"
  148. 7340  DATA  ECLECTIC,"BEST OF VARIED SOURCES"
  149. 7350  DATA  VIRGULE,"A SLASH AS /."
  150. 7360  DATA  HUBIS,"SENCE OF POWER THAT LEADS TO A FALL."
  151. 7370  DATA DENDROCHRONOLOGY,"TREE RING DATING."
  152. 7380  DATA LACERATE,"TEAR TO PIECES, CUT,MANGLE"
  153. 7390  DATA RUFFLE,"DISARRANGE,RIPPLE,IRRITATE"
  154. 7400  DATA UNABASHED,"UNDAUNTED,BOLD,UNDISMAYED"
  155. 7999  DATA XXX